Array.concat()

Доступность

Flash Player 5.

Синтаксис

my_array.concat( [ value0:Object, value1,...valueN ]) : Array

Параметры

value0,...valueN Числа, элементы или строки, добавляемые в конец my_array , с образованием нового массива. Если Вы не передаёте никаких параметров, создаётся дубликат my_array .

Возвращает

Новый массив.

Описание

Метод; конкатенирует/связывает/ элементы, определённые в параметрах, с элементами в my_array, и создает новый массив. Если value одного или нескольких параметров являются массивом, связываются элементы этого массива, а не непосредственно массив. Массив my_array при этом, остаётся неизменным.

Пример

Следующий код связывает два массива :

var alpha_array:Array = new Array("a","b","c");
var numeric_array:Array = new Array(1,2,3);
var alphaNumeric_array:Array =alpha_array.concat(numeric_array); 
trace(alphaNumeric_array);
// создан массив [a,b,c,1,2,3]

Следующий код связывает три массива :

var num1_array:Array = [1,3,5];
var num2_array:Array = [2,4,6];
var num3_array:Array = [7,8,9];
var nums_array:Array=num1_array.concat(num2_array,num3_array) 
trace(nums_array);
// создан массив [1,3,5,2,4,6,7,8,9]

Вложенные массивы не связываются тем же способом, что и обычные массивы. Элементы вложенного массива не присутствуют в массиве x_array , как отдельные элементы, что показано в следующем примере :

var a_array:Array = new Array ("a","b","c");

// 2 и 3 - элементы вложенного массива
var n_array:Array = new Array(1, [2, 3], 4); 

var x_array:Array = a_array.concat(n_array);
trace(x_array[0]); // a
trace(x_array[1]); // b
trace(x_array[2]); // c
trace(x_array[3]); // 1
trace(x_array[4]); // 2, 3 
trace(x_array[5]); // 4

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление